Hamilton C shell Sample: Makelinks.csh

Makelinks.csh


#  Transform a Microsoft Internet Explorer Favorites list into
#  a links.htm web page.

#  A link will be listed only if it is in a subdirectory and only if
#  it and the directory are not marked with the System bit; this provides
#  a simple method of marking which items are to be published and which
#  are to be kept private.

#  If it exists, any description file in the Favorites directory will
#  be copied to the beginning of the links.htm page and any description
#  files in the subdirectories will be copied to the beginning of the
#  listing of that category.

#  Copyright (c) 1997-2001 by Hamilton Laboratories.  All rights reserved.

proc intro( title )
   echo "<HTML>"
   echo "<HEAD>"
   echo "<TITLE>$title</TITLE>"
   echo "</HEAD>"
   echo
   echo "<META NAME=^"description^" CONTENT=^"Links to other interesting"
   echo "sites, not all purely business-related.^">"
   echo
   echo "<BODY BGCOLOR=^"#FFFFFF^" TEXT=^"#000000^" LINK=^"#0000CC^" VLINK=^"#880077^">"
   echo "<H2><FONT FACE=^"Arial,Helvetica,Geneva^" COLOR=^"#CC0000^">"
   echo "Links"
   echo "</FONT></H2>"
   echo "<P><BR></P>"
   echo "<BLOCKQUOTE>"
end

proc list( dir )
   local i
   echo "<P><BR><BR></P>"
   echo "<H3><FONT FACE=^"Arial,Helvetica,Geneva^" COLOR=^"#CC0000^">"
   echo "<A NAME=^"$dir:t:gS/ //^">$dir:t</A>:</FONT></H3>"
   echo "<BLOCKQUOTE>"
   if (-e $dir\Description) then
      echo "   <P>"
      cat $dir\Description
      echo "   </P>"
   end
   echo "   <BLOCKQUOTE>"
   echo "      <P>"
   foreach i ($dir\*.url)
      if (! -S $i) then
         echo "      <A HREF=^"`sed -n s/URL=//p $i`^">$i:b</A><BR>"
      end
   end
   echo "      </P>"
   echo "   </BLOCKQUOTE>"
   echo "</BLOCKQUOTE>"
end

proc trailer( )
   echo "<P><BR><BR></P>"
   echo "<CENTER>"
   echo "<P>"
   echo "<A HREF=^"cshell.htm^">Hamilton C shell</A> |"
   echo "<A HREF=^"updates.htm^">Free Updates</A> |"
   echo "<A HREF=^"demopage.htm^">Free Demo Software</A> |"
   echo "<A HREF=^"win32class.htm^">Win32 Training</A>"
   echo "<BR>"
   echo "<A HREF=^"y2k.htm^">Y2K</A> |"
   echo "<A HREF=^"testimon.htm^">Customer Testimonials</A> |"
   echo "<A HREF=^"userguid/userguid.htm^">On-line Hamilton C shell User Guide</A>"
   echo "<BR>"
   echo "<A HREF=^"index.htm^">Home</A> |"
   echo "<A HREF=^"mailto:Nicole Hamilton <hamilton@hamiltonlabs.com>^">Email</A> |"
   echo "<A HREF=^"support.htm^">Support</A> |"
   echo "<A HREF=^"profile.htm^">Company Profile</A> |"
   echo "<A HREF=^"distributors.htm^">Distributors</A> |"
   echo "Links"
   echo "</P><BR><BR><P>"
   echo "<SMALL>"
   echo "Copyright &copy; 1997-2001 by Hamilton Laboratories."
   echo "All rights reserved.<BR>"
   echo "You are vistor number"
   echo "<!--#exec cmd=^"count.cgi^"-->."
   echo "This page was last modified `date -n +'%B %e, %Y'`."
   echo "</SMALL>"
   echo "</P>"
   echo "</CENTER>"
   echo "</BODY>"
   echo "</HTML>"
end

proc makelinks( dir )
   local i

   if ($#dir == 0) set dir = $UserProfile\favorites

   if (! -e $dir) then
      echo -2 $dir does not exist
   else
      @ dir = $dir:M

      (intro "Hamilton Laboratories Links Page"
      if (-e $dir\Description) then
         echo "<P>"
         cat $dir\Description
         echo "</P>"
      end

      echo "<P>"
      echo "Links are broken up into the following categories:"
      echo "</P>"
      echo "<BLOCKQUOTE><BLOCKQUOTE>"
      echo "   <P>"

      foreach i ($dir\*)
         if (-D $i && ! -S $i) then
            echo "   <A HREF=^"#$i:m:t:gS/ //^">$i:m:t</A><BR>"
         end
      end

      echo "   </P>"
      echo "</BLOCKQUOTE></BLOCKQUOTE>"
      echo "<P>"
      echo "(This page was created from our own Internet Explorer Favorites"
      echo "list with <A HREF=^"makelinks.htm^">a C shell script</A>.)"
      echo "</P>"
      echo "<P>"
      echo "<A HREF=^"http://www.netmind.com/cgi-bin/uncgi/url-mind?links^">"
      echo "Register to get email when this page changes.</A>"
      echo "</P>"

      foreach i ($dir\*)
         if (-D $i && ! -S $i) list $i:m
      end
      trailer) | dim > links.htm
   end

end
   
makelinks $argv
Hamilton C shell | Free Updates | Free Demo Software | Win32 Training
Y2K | Customer Testimonials | On-line Hamilton C shell User Guide
Home | Email | Support | Company Profile | Distributors | Links